/* 
spl_off.cdp - By Mark Reimer - 4-21-98 
Creates offset splines on both sides of a selected spline 
at a specified distance 
*/ 

/* initialize local variables */ 
local offset,enttype,dims,segs,j,k,A,B,C,D,E,F,G,H 
local x,y,ang,track,vm 

local double nodept[0][0] 
local double fdat[0] 

/* dimension arrays */ 
array nodept[210][2] 
array fdat[1600] 

offset = 1 

:getwidth 
getflt "Enter the spline offset distance (%f) =>",offset,offset 
on (@key + 3) goto exit, exit, 

:select 
getent "Select spline to offset", enttype, ,fdat 
on (@key + 3) goto exit, getwidth, 

if (@error == 0) 
goto goodselect 

pause "Error selecting spline... Press Return" 
goto select 

:goodselect 
dims = @intdat[8] 
segs = @intdat[11] 

/* make sure it's 2d */ 
if (dims == 0) 
goto drawtrack 

pause "Must be a 2d Spline... Press Return" 
goto select 

:drawtrack 
/* Get construction view matrix and place in array */ 
getview @intdat[10],vm 
view 1,vm[0],vm[1],vm[2],vm[3],vm[4],vm[5],vm[6],vm[7],vm[8] 

for (track=1;track<3;track=track+1) 
{ 
prompt "Processing spline %d...Please wait", track 

if (track == 2) 
offset = -offset 

for (j=0;j<segs;j=j+1) 
{ 
k=j * 8 
A=fdat[k + 1] 
B=fdat[k + 2] 
C=fdat[k + 3] 
D=fdat[k + 4] 
E=fdat[k + 5] 
F=fdat[k + 6] 
G=fdat[k + 7] 
H=fdat[k + 8] 

x=D 
y=H 

/* tangent slope of curve at start (u=0) dy/dx is G/C */ 
ang = atan2(G,C) 

nodept[j][0] = x - offset*sin(ang) 
nodept[j][1] = y + offset*cos(ang) 
} 

/* For last node point find perp end coord of spline segment */ 
/* find end point of selected spline */ 
x=A+B+C+D 
y=E+F+G+H 

/* tangent slope of curve at end (u=1) dy/dx 
is (3*E + 2*F +G) / (3*A + 2*B + C) */ 
ang = atan2((3*E + 2*F +G), (3*A + 2*B + C)) 

nodept[segs][0] = x - offset*sin(ang) 
nodept[segs][1] = y + offset*cos(ang) 

/* draw offset spline */ 
spline P2NN,nodept,segs+1,fdat[0],1 
} 

goto select 

:exit 

clear offset,enttype,dims,segs,j,k,A,B,C,D,E,F,G,H 
clear x,y,ang,track,vm,nodept,fdat